xonecas.io
79113
Ma

mini-coding-agent / files

mini-coding-agent / src / headless.zig

2.9 KB
1const std = @import("std");
2const platform = @import("platform.zig");
3const time = @import("time.zig");
4const config = @import("config.zig");
5const message_mod = @import("message.zig");
6const agent = @import("agent.zig");
7
8var cancel = std.atomic.Value(bool).init(false);
9var caught_signal = std.atomic.Value(u32).init(0);
10
11fn onSignal(sig: std.posix.SIG) callconv(.c) void {
12    caught_signal.store(@backingInt(sig), .seq_cst);
13    cancel.store(true, .release);
14}
15
16const PrintCtx = struct { failed: bool = false };
17
18fn printEvent(ctx: *anyopaque, event: agent.Event) void {
19    const pc: *PrintCtx = @ptrCast(@alignCast(ctx));
20    switch (event) {
21        .retry => |r| platform.printErr("[retry] {s}: attempt {d}/{d} in {d}ms\n", .{ r.reason, r.attempt, r.total, r.delay_ms }),
22        .tool_call => |call| platform.printErr("[tool] {s}\n", .{call.name}),
23        .tool_output => |chunk| platform.writeErr(chunk),
24        .no_model => {
25            pc.failed = true;
26            platform.printErr("[error] no model configured; add \"provider\" and \"model\" to {s}\n", .{config.configPath(platform.gpa)});
27        },
28        .err => |message| {
29            pc.failed = true;
30            platform.printErr("[error] {s}\n", .{message});
31        },
32        .cancelled => {
33            pc.failed = true;
34            platform.printErr("[cancelled]\n", .{});
35        },
36        else => {},
37    }
38}
39
40pub fn run(a: std.mem.Allocator, prompt_text: []const u8, opts: agent.Options, resumed: []const message_mod.Message) u8 {
41    var messages: std.ArrayList(message_mod.Message) = .empty;
42    messages.appendSlice(a, resumed) catch {
43        platform.printErr("[error] out of memory\n", .{});
44        return 1;
45    };
46    const user = message_mod.Message{ .user = .{ .content = prompt_text, .timestamp = time.nowMs() } };
47    messages.append(a, user) catch {
48        platform.printErr("[error] out of memory\n", .{});
49        return 1;
50    };
51    opts.session.appendMessage(a, user) catch |e| {
52        platform.printErr("[error] {s}\n", .{@errorName(e)});
53        return 1;
54    };
55
56    platform.onSignal(.INT, onSignal);
57    platform.onSignal(.TERM, onSignal);
58
59    var pc = PrintCtx{};
60    var o = opts;
61    o.cancel = &cancel;
62    agent.runTurn(o, &messages, null, .{ .ctx = &pc, .on_event = printEvent });
63    opts.session.close();
64    const sig = caught_signal.load(.seq_cst);
65    if (sig != 0) platform.reRaise(@fromBackingInt(@intCast(sig)));
66    if (pc.failed) return 1;
67
68    var i = messages.items.len;
69    const last = while (i > 0) {
70        i -= 1;
71        if (messages.items[i] == .assistant) break messages.items[i].assistant;
72    } else return 0;
73    const text = last.text(a) catch {
74        platform.printErr("[error] out of memory\n", .{});
75        return 1;
76    };
77    if (text.len > 0) {
78        platform.writeOut(text);
79        if (text[text.len - 1] != '\n') platform.writeOut("\n");
80    }
81    return 0;
82}